Range Object - Excel 97 - vba - 表計算゛ (Hyo-Kei-Zan)

実例

セルを順に処理する

Range Object の持つセルを順に処理します。これは 8 回のループになります。

Sub range34()
    Dim x As Range, y As Range
    Set x = Sheet1.Range("B5:E6")
    For Each y In x
        MsgBox y.Address, vbOKOnly, y.Value
    Next y
End Sub

Range Object の持つセルを順に処理します。これは 8 回のループになります。

Sub range35()
    Dim x As Range, i As Long
    Set x = Sheet1.Range("B5:E6")
    For i = 1 To x.Count
        MsgBox x(i).Address, vbOKOnly, x(i).Value
    Next i
End Sub

行単位で処理する

Range Object を行単位で処理します。これは 2 回のループになります。

Sub range36()
    Dim x As Range, y As Range
    Set x = Sheet1.Range("B5:E6").Rows
    For Each y In x
        MsgBox y.Address, vbOKOnly, y.Cells.Count
    Next y
End Sub

Range Object を行単位で処理します。これは 2 回のループになります。

Sub range37()
    Dim x As Range, i As Long
    Set x = Sheet1.Range("B5:E6").Rows
    For i = 1 To x.Count
        MsgBox x(i).Address, vbOKOnly, x(i).Cells.Count
    Next i
End Sub

列単位で処理する

Range Object を列単位で処理します。これは 4 回のループになります。

Sub range38()
    Dim x As Range, y As Range
    Set x = Sheet1.Range("B5:E6").Columns
    For Each y In x
        MsgBox y.Address, vbOKOnly, y.Cells.Count
    Next y
End Sub

Range Object を列単位で処理します。これは 4 回のループになります。

Sub range39()
    Dim x As Range, i As Long
    Set x = Sheet1.Range("B5:E6").Columns
    For i = 1 To x.Count
        MsgBox x(i).Address, vbOKOnly, x(i).Cells.Count
    Next i
End Sub

複雑な領域を単純な領域に分けて処理する

Range Object を単純な Range Object に分けて処理します。これは 2 回のループになります。

Sub range40()
    Dim x As Range, y As Range
    Set x = Sheet1.Range("B5:E6,G3:H4")
    For Each y In x.Areas
        MsgBox y.Address, vbOKOnly, y.Count
    Next y
End Sub

Range Object を単純な Range Object に分けて処理します。これは 2 回のループになります。

Sub range41()
    Dim x As Range, i As Long
    Set x = Sheet1.Range("B5:E6,G3:H4")
    For i = 1 To x.Areas.Count
        MsgBox x.Areas(i).Address, vbOKOnly, x.Areas(i).Count
    Next i
End Sub

データに依存したループ

Range Object をデータのある範囲で、行単位にループします。このように、都度、値を読んで判断する方法は、条件を柔軟に決められますが、効率は悪くなります。
```
Sub range42()
    Dim x As Range, i As Long
    Set x = Sheet1.Range("B5").Rows
    i = 1
    Do While x(i).Value <> ""
        MsgBox x(i).Address
        i = i + 1
    Loop
End Sub
```
Range Object をデータのある範囲で、行単位にループします。このように、 End を使えば、最初にループ回数を特定できます。ただし、データが 1 行しかなければ、 End は、シートの端まで飛んでしまうので、注意が必要です。
```
Sub range43()
    Dim x As Range, y As Range, i As Long
    Set x = Sheet1.Range("B5")
    Set y = x.End(xlDown)
    For i = 1 To y.Row - x.Row + 1
        MsgBox x(i).Address
    Next i
End Sub
```
Range Object をデータのある範囲で、行単位にループします。このように、CurrentRegion を使えば、コードがすっきりしますが、正しい範囲を取得できるよう、シートの構成に気をつけなければなりません。
```
Sub range44()
    Dim x As Range, y As Range
    Set x = Sheet1.Range("B5").CurrentRegion.Rows
    For Each y In x
        MsgBox y.Address, vbOKOnly, y.Cells.Count
    Next y
End Sub
```

Range Object - Excel 97

はじめに

実例

セルを順に処理する

行単位で処理する

列単位で処理する

複雑な領域を単純な領域に分けて処理する

データに依存したループ

Download a Sample Code

History